GREET강의(3) - 그레이수소
가장 경제적이지만 아직까지 해결해야할 것들이 많긴 합니다.
들어가며
이번에는 수소에 대해 알아볼까요?
수소에너지를 사용하면 엔진에서의 연소도, 연료전지에서의 발전도 탄소배출이 없어 최근 차세대 에너지원으로 수소에너지에 대한 관심이 급증하고 있습니다.
<제1차 수소경제 이행 기본계획>
http://www.motie.go.kr/motie/ne/announce2/bbs/bbsView.do?bbs_seq_n=67130&bbs_cd_n=6
하지만 LCA 관점에서 분석한다면 어떨까요? 당연히 탄소배출량은 0이 아니겠죠?
이번 시간에는, Natural gas를 feed로, SMR 과정을 거쳐 생산한 그레이수소의 LCA 탄소배출량을 GREET2021에서 분석해보겠습니다.
Types of hydrogen fuel - Energy Education그레이수소 전과정 탄소 배출량
자 그럼 GREET2021을 준비하고, Hydrogen Sheet의 B~C열 254~271행을 봐주세요.
해당 항들이 Natural gas SMR 과정을 통한 그레이수소 생산과 관련된 배출량 데이터 입니다.
Feed인 Natural gas 1mmbtu 생산 시 CO2 배출량 4,628g(B271),
SMR등 그레이수소 생산공정의 Loss factor 0.827(C254),
그레이수소 1mmbtu 생산 시 CO2 배출량 89,971g(C271) 데이터가 있네요.
이를 통해 우리는 SMR 공정으로 수소 1mmbtu 생산 시 전 과정 배출량을
B271*C254+C271 = 93,797g/mmbtu와 같이 계산할 수 있습니다.
수소 1mmbtu 생산 당 이산화탄소가 약 93,797g 배출된다는 데이터인데요, mmbtu 단위를 우리에게 조금 더 친숙한 GJ 단위로 변환해볼까요?
1mmbtu = 1.055GJ 이므로, 기체수소 1GJ 생산 시 이산화탄소는 약 88,903g 배출되네요.
이는 88.9 g/MJ 이고 유럽의 청정수소 인증제를 주관하는 CertifHy의 그레이수소 기준치인 91 g CO2e/MJ과 흡사한 것을 확인할 수 있습니다.
(우리가 GREET에서 확인한 값은 CO2이고 CertifHy의 값은 CO2eq로 다르며 자세한 설명은 추후 용어만 따로 정리한 포스트를 작성해보겠습니다.)
이번엔 에너지단위를 부피단위로 변환해볼까요? 이 과정에서 저위발열량이라는 물리량을 활용합니다.
GREET의 Fuel_Specs Sheet에서 Gaseous hydrogen의 LHV값을 찾으면 되는데요,
B72항이고, 그 값은 290Btu/ft3입니다.
아까 배출량에 다음과 같은 계산을 하면 되는데, 93,797g/mmbtu * 290Btu/ft3 /1,000,000 =
27.201g/ft3과 같습니다.
ft3 = 0.02832 m3이므로, 960.487g/m3으로도 변환되네요.
이번에는 위에서 다룬 Feedstock 배출량 B271항과, Fuel 과정 배출량 C271항의 데이터가 어떻게 계산되어있는지 하나 하나 분석해보겠습니다.
Feedstock
그레이수소의 Feed인 Natural gas의 upstream 배출량을 구하는 과정입니다.
B271항을 클릭하고, 상단 수식을 볼까요?
(IF(Inputs!$F$239=1,(MMULT(NG!$K66:$L66,Inputs!$F$117:$F$118)*NG!$M$25+NG!M66+NG!N66),
IF(Inputs!$F$239=2,(NG!F101*NG!G$84+NG!G101),
IF(Inputs!$F$239=4,RNG!Y287,(NG!H101*NG!I$84+NG!I101))))
*NG!$Z$25+NG!$Z66)*
(1000000+IF(B$21=1,0,-$B$196-$E$196*kWh2BTU))/1000000*IF(B$21=1,1,IF(B$21=2,B$29,B$35))
Inputs!F239항의 값에 따라 다른 계산식이 선택되네요. Inputs에서 해당 항이 어떤 항인지 찾아볼까요?
Feedstock으로써 Natural gas에 대한 선택 옵션이네요.
F239항이 1이면, (NG!$K66*Inputs!$F$117+NG!$L66*$F$118)*NG!$M$25+NG!M66+NG!N66)에,
F239항이 2이면, (NG!$F101*NG!$G$84+NG!$G101)에,
F239항이 4이면, (RNG!$Y287)에,
F239항이 1,2,4모두 아니면 (NG!$H101*NG!$I$84+NG!$I101)에 뒤에 따르는 파란색, 노란색 항들을 곱하는 구조입니다.
그럼 잠시 NG Sheet에서 저 파란색 두 항을 찾아볼까요? 이 항들은 IF문에 영향을 받지 않네요.
앞 부분 계산식의 결과값에 곱해지는 Z25항은 Loss factor였고, 후에 더해지는 Z66항은 Hydrogen Plant까지 운송과정 배출량입니다.
따라서 운송과정 배출량에 더해지는 Input Sheet의 F239항으로 결정되는 앞 부분의 값은, 운송과정 직전까지, Natural gas 생산과 관련된 배출량이겠다는 생각이 듭니다.
이후 Z25항, Z66항과의 계산을 통해 전체 Upstream이 배출량 계산이 마무리되는 구조겠네요.
그럼 F239항에 따라 다른 Upstream이 결정될텐데, IF문을 정리해가면서 분석해보겠습니다.
Upstream 이후의 큰 흐름을 먼저 보고싶으시면 아래로 조금만 스크롤을 내려서 노란색 계산식을 분석하는 부분으로 넘어가시면 됩니다!
1. F239 = 1일 때
(NG!$K66*Inputs!$F$117+NG!$L66*$F$118)*NG!$M$25+NG!M66+NG!N66
NA(North America)에서, NG를 Recovery하고, Processing하는 과정에서 총 배출량과, Non - Combustion emission을 더한 배출량입니다.
초반에 Inputs Sheet의 F117, F118항을 NG Recovery, 셰일가스 Recovery 과정의 배출량 K66, L66항에 각각 곱해서 더했는데, 해당 Inputs항들은 NG와 셰일가스의 비율을 뜻하는 것입니다. 따라서 위 계산식은 NG와 Shale 이라는 종류를 반영한 배출량임을 알 수 있습니다.
2. F239 = 2일 때
(NG!$F101*NG!$G$84+NG!$G101)
액화 과정을 거친 Natural gas(LNG) 에 해당하는 경우의 계산식이라는 것을 알 수 있습니다.
3. F239 = 4일 때
RNG!$Y287항이 선택되는데, RNG Sheet에서 해당 항을 찾아보면, Intermediate Fuel로써의 Natural gas 를 뜻하는 항이라는 것을 알 수 있습니다.
4. F239항이 1, 2, 4 어떤 값도 아닐 때
NG!$H101*NG!$I$84+NG!$I101
Flare gas를 생산하고, 이를 intermediate fuel로써의 액화 Natural gas로 processing하는 공정을 통해 생산한 Natural gas의 경우입니다.
지금까지, F239항으로 어떤 Natural gas를 사용하는지 선택하고, 그에 따른 각각의 배출량을 계산한 과정이었습니다.
그렇게 계산된 값에, NG!$Z$25, NG!$Z66 항을 곱하고 더해서 Natural gas 생산부터 수소생산지까지 운송하기까지, Upstream 배출량을 계산하게 됩니다.
자 그럼 이후에 곱해지는,
(1000000+IF(B$21=1,0,-$B$196-$E$196*kWh2BTU))/1000000*IF(B$21=1,1,IF(B$21=2,B$29,B$35)와 같은 계산식이 뜻하는 것은 무엇일까요?
이는 Allocation에 관련된 계산과정입니다. 이 또한 Hydrogen Sheet의 B21항에 따라 계산이 달라지는데, 각 경우에 따라 계산식을 정리하면 다음과 같습니다.
1. B21 = 1
B21항이 1일 때는 Steam과 Electricity를 By-product로 취급하겠다는 뜻인데요, Co-product로 취급하면 우리가 원하는 Product와 함께 총 배출량을 할당하는데 반에, Bi-product로 취급하면 배출량을 할당하지 않아요. 따라서 위 Allocation 항은 다음과 같이
*(1000000+0)/1000000*1) = 1
이 되어서, 앞에서 구한 NG의 Upstream에 이를 곱해도 값이 달라지지 않겠습니다.
2. B21 = 2 or 3
B21항이 2, 3일때는 Co-product인 Steam과 Electricity와 Natural gas에게 배출량을 할당하게 되는데요, 2일때는 Energy 기준으로, 3일때는 Market Value 기준으로 할당합니다.
기존에 구한, 전체 Upstream에
*(1000000-$B$196-$E$196*kWh2BTU))/1000000*B$29
을 곱합니다. (B21 = 3일 때는 B29 대신 B35이 선택되어 곱해집니다.)
곱해지는 계산식을 볼까요? B196과 E196을 빼주는 것을 확인할 수 있는데, 해당 항들을 찾아보면, "Steam or electricity export Btu or KWh per mmBtu of fuel produced"을 의미한다는 것을 알 수 있습니다.
B196은 Steam, E196은 Electricity의 energy량입니다.
이들 Co - product를 반영하면, 기존에 계산할 때보다 Natural gas (+ Co-product)를 더 많이 생산해야겠죠? 우리가 원하는 것은 순수한 Natural gas 1mmbtu이니까요. 당연히 배출량도 같은 비율로 증가할것입니다.
1mmbtu 중에 1,000,000/1,145,000 (68.976...%)만이 Natural gas이기 때문에, 반대로 1,145,000/1,000,000을 곱해서 이를 보정해주는데, 위 식의 빨간 부분이 이에 해당하는 계산식입니다.
그렇다면 이제 뒤에 곱해진 B29, B35항을 찾아볼까요? 조금 스크롤을 올리면 찾을 수 있네요, 이들은 각각 Energy, Market value Allocation Factor를 뜻합니다. 이들 factor를 곱해주어 할당을 하게 됩니다.
그렇다면 Feedstock인 Natural gas 1mmbtu 생산과정의 배출량 계산식에 대한 설명이 마무리되는데요, 계산식을 다시 보면서 마지막으로 정리해볼까요?
=(IF(Inputs!$F$239=1,(MMULT(NG!$K66:$L66,Inputs!$F$117:$F$118) *NG!$M$25+NG!M66+NG!N66),IF(Inputs!$F$239=2,(NG!F101*NG!G$84+NG!G101),IF(Inputs!$F$239=4,RNG!Y287,(NG!H101*NG!I$84+NG!I101))))
*NG!$Z$25+NG!$Z66)*(1000000+IF(B$21=1,0,-$B$196-$E$196*kWh2BTU))/1000000*IF(B$21=1,1,IF(B$21=2,B$29,B$35))
Feedstock이 되는 Natural gas의 종류에 따라 다른, 생산과정의 탄소배출량에
수소 Plant까지 옮기는, 운송 시 탄소배출량을 더해 계산한 NG Upstream을
Natural gas와 함께 생산된 Co-product와 Allocation해서
Natural gas 1mmbtu에 해당하는 전 과정 탄소배출량을 계산하는 과정이었습니다.
Fuel
이번에는 Natural gas를 SMR 등의 공정을 통해 기체수소로 만드는 공정에서의 탄소배출량을 분석해봅시다.
C271항을 클릭하고 상단 수식을 볼까요?
((B236+C236
+IF($B$21=1,IF(Inputs!$F$251=1,D236*B$196/1000000,IF(Inputs!$F$251=2,$E$196*(1-Electric!$D$101*$F236,0)),0))*IF(B$21=1,1,IF(B$21=2,B$29,B$35))
*G$194+G236)*$H$194
+H236+I236
처음 더해지는 두 항인 B236, C236은 어떤 항일까요?
두 항은 Gaseous Hydrogen을 생산하는 과정에서의 배출량을 뜻하는 것이었네요.
B236항의 배출량은 Process fuel의 upstream + Process fuel의 연소배출량이고, C236항은 Non-combustion emission이라는 것을 알 수 있습니다. (B236항의 경우, 조금 특별한 계산식이 있어서 마지막에 이에 대한 설명이 추가되었습니다.)
이후에 조건문이 등장하고, G194, H194항이 곱해지고 G236, I236항이 더해지며 이어지네요.
조건문을 분석하기 전에, 조건문과 관계없이 일정한 이 항들을 찾아볼까요?
194행의 항들은 Loss factor였고, G236항은 T&D 과정의 배출량, H236항은 기체수소를 압축, 냉각하는 과정의 배출량, I236항은 Flare gas와 관련된 배출량이네요.
여기까지 정리한 내용을 봤을 때, 중간에 조건문을 제외하면 기체수소를 생산, 운반, 압축하는 과정의 배출량이 계산되겠죠?
그럼 우리가 계산하고자 하는 배출량 결과값이 다 구해진 것 아닐까 싶은데, 중간의 조건문은 allocation과 관련된 계산식입니다. 배출량 결과값에, 설정한 allocation 방식에 따라 할당하는 과정이겠죠?
자 그럼 이제 IF문을 뜯어봅시다.
IF($B$21=1,IF(Inputs!$F$251=1,D236*B$196/1000000,IF(Inputs!$F$251=2,$E$196*(1-Electric!$D$101*$F236,0)),0
이번에도 B21항으로 Mode를 설정하네요.
B21 항이 1일 때는 Steam과 Electricity를 By-product로 처리하는 모드였고, 2나 3일때는 energy, market value에 대해 할당하는 모드였습니다.
B21항이 1일 때는 다음과 같은 식이 계산되고
(B236+C236+IF(Inputs!$F$251=1,D236*B$196/1000000,IF(Inputs!$F$251=2,$E$196*(1-Electric!$D$101*$F236,0)),0))*G$194+G236)*$H$194+ H236+I236
B21항이 2나 3일 때는, 즉 Steam과 Electricity가 Co-product로 처리할 때는 다음과 같이 비교적 간단한 계산식으로 바뀝니다.
((B236+C236)*B29*G$194+G236)*$H$194+ H236+I236 (B21 = 2일 때)
B21항이 2일때는 Energy allocation factor인 B29항을, B21항이 3일때는 Market value allocation factor인 B35항을 곱해주네요.
B236+C236과정, 즉 기체 수소를 생산하는 과정에서 Steam이나 Electricity와 같은 Co-product가 발생하니까, 해당 allocation factor를 (B236+C236)에 곱해주어 할당하는 것을 알 수 있습니다.
자 그럼 지금까지, Feedstock upstream 배출량과, 이를 수소로 바꾸는 Fuel 배출량에 대해 분석했습니다.
B236항 - CCUS
잠시 B236항을 클릭하고 상단 수식을 봐주세요.
Fuel 배출량 계산식에서 등장한 항이었는데요, 처음 설명드릴 때 B236항이 "수소 생산 시 배출되는 배출량 값"이라고 설명하고 넘어갔는데, 수식을 보면 이 값이 단순히 입력된 값이 아니라, 또 다른 계산식을 통해 계산된 데이터라는 것을 알 수 있습니다.
심지어 이 계산식에는 Process fuel의 Upstream, 연소배출량 뿐만 아니라 지금껏 GREET에서 보여드리지 않은 계산이 추가되어 있어서, 이 B236항의 계산이 어떻게 이루어졌는지 설명해드리려 합니다.
계산식을 들여다 보기 전에, 해당 배출량이 어떻게 계산이 되었을지 예상해볼까요?
방금 언급했듯, 수소를 생산하는 공정의 연료로써 투입되는 Process fuel들의 upstream들과, 그들을 연소시킬 때 배출되는 연소배출량들의 합으로 배출량을 계산하겠죠?
그럼 이제 계산식을 가져와서, 계산식을 다음과 같이 쪼개보겠습니다.
(
B$208*(B$176*EF!$M16+Petroleum!$B279*Petroleum!$I$262+Petroleum!$I279)
+B$209*(B$177*EF!$R16+B$178*EF!$S16+B$179*EF!$T16+Petroleum!$B279*Petroleum!$J$262+Petroleum!$J279)
+B$210*(EF!$V16+Petroleum!$B279*Petroleum!$D$262+Petroleum!$D279)
+B$211*(EF!$BY16+IF(Inputs!$F$239=1,MMULT(NG!$K66:$L66,Inputs!$F$117:$F$118)*NG!$M$25+NG!$M66+NG!$N66,IF(Inputs!$F$239=2,NG!$F101*NG!$G$84+NG!$G101,IF(Inputs!$F$239=4,RNG!$Y287,NG!$H101*NG!$I$84+NG!$I101)))*NG!$Z$25+NG!$Z66)
+B$217*(Electric!$B220+Electric!$C220)
)/1000000
-$B$11*((10^6/B192*B195+B$211)/Fuel_Specs!$B$70*Fuel_Specs!$E$70*Fuel_Specs!$F$70/Fuel_Specs!$B$146)
B208, 209, 210, 211, 217항에, 뒤 계산식이 곱해져서 더하고,
이것에 1,000,000을 나눠주고요,
B11 항에 노란색 계산식을 곱하고 빼주네요
하나하나 GREET에서 찾아가면서 이해해봅시다.
B208~217항들은 기체수소 1mmbtu 생산 시 투입되는 Process fuel들의 에너지량이었네요.
그렇다면 이들 뒤에 각각 곱해진 계산식 묶음은, 각 연료들의 Upstream과, 각 연료를 연소시킬 때의 배출량의 합을 나타내겠죠?
하나 하나 찾아볼까요?
1. B208 (Residual oil)
B$208*(B$176*EF!$M16+Petroleum!$B279*Petroleum!$I$262+Petroleum!$I279)
B208 항 뒤에 곱해진 계산식을 보면, B176에 EF Sheet의 M16을 곱하고, 그 후 Petroleum Sheet의 항들이 더해지네요.
스크롤을 조금 올리면 B176항을 찾을 수 있는데요, B176~B187항은 수소 Plant에서 연소 방식의 비율을 뜻합니다. 같은 연료라도 연소 방식이 달라지면 배출량이 달라지므로 해당 비율을 고려해준다는 것을 알 수 있습니다.
그리고 배출계수를 참조할 수 있는 EF Sheet의 M16항은, Residual oil 1mmbtu를, B176에 해당하는 Commercial boiler 방식으로 연소시킬 때 배출량을 뜻합니다.
그럼 뒤의 초록 부분은 Upstream이겠죠? Petroleum Sheet에서 찾아보면 다음과 같이 Residual oil의 upstream이라는 것을 알 수 있습니다.
(Upstream = B279*I262+I279)
2. B209 (Diesel fuel)
B$209*(B$177*EF!$R16+B$178*EF!$S16+B$179*EF!$T16+Petroleum!$B279*Petroleum!$J$262+Petroleum!$J279)
Residual oil과 비슷한데요, B209는 Diesel fuel의 에너지 투입량을 뜻하고, B177, B178은 연소방식이며 각각에 곱해지는 EF Sheet의 두 항은 해당 연소방식 각각의 배출량입니다.
뒤 Petroleum Sheet 항들의 계산식은 Upstream이겠죠? 이것도 Petroleum Sheet에서 찾아볼까요?
(Upstream = B279*J262+J279)
3. B217 (Electricity)
B$217*(Electric!$B220+Electric!$C220)
전기는 직접 연소에 활용하지 않기 때문에 배출계수를 정의하지 않습니다. 따라서 전기의 경우 에너지 사용량에 Upstream만 곱해주게 되는데요, 뒤에 곱해진 두 항을 Electric Sheet에서 찾아볼까요?
Stationary use를 위한 전기에너지의 Feedstock + Fuel, 즉 Upstream을 의미하는것이죠.
4. B211 (Natural gas)
B$211*(EF!$BY16+IF(Inputs!$F$239=1,MMULT(NG!$K66:$L66,Inputs!$F$117:$F$118)*NG!$M$25+NG!$M66+NG!$N66,IF(Inputs!$F$239=2,NG!$F101*NG!$G$84+NG!$G101,IF(Inputs!$F$239=4,RNG!$Y287,NG!$H101*NG!$I$84+NG!$I101)))*NG!$Z$25+NG!$Z66)
Natural gas에선 조금 특별한 계산식으로 구한 항이 있는데요, B211항입니다.
B192항의 수소 생산 공정의 Energy efficiency를 볼까요?
GREET에서 Efficiency는 (Energy of Product)/(Energy of feedstock + Energy of Process fuels)로 정의됩니다.
이 공정에서 Process fuel로 사용되는 연료는 Natural gas밖에 없고, Feedstock 또한 Natural gas이므로, 1,000,000/B192 = 수소 1mmbtu 생산 시 투입되는 모든 (Feedstock로써 + Fuel로써) Natural gas의 에너지 input량이겠죠?
그리고 B195항에는, "Share of Feedstock input as feed" 값이 정의되어있습니다. 이는 투입된 전체 Natural gas중에, 59.4%가 Feed로 투입되고, 나머지 40.6%는 Process fuel로써 사용된다는 뜻입니다. 따라서 전체 Natural gas의 에너지량에 (1-B195)를 곱하면 Process fuel NG 투입량을 구할 수 있겠습니다. 수식은 다음과 같습니다.
B211 = (1,000,000/B192)*(1-B195)
이렇게 구한 Natural gas 투입량에 배출계수와 Upstream이 더해지는데, Upstream 계산식은 Feedstock 배출량에 사용된 수식과 동일합니다.
그 앞에 더해진 EF Sheet의 항은 Natural gas의 배출계수이구요.
그렇다면 다음의 B236항의 계산식 중에서, Process fuel에 관련된 부분에 대한 설명이 끝났습니다.
(
B$208*(B$176*EF!$M16+Petroleum!$B279*Petroleum!$I$262+Petroleum!$I279)
+B$209*(B$177*EF!$R16+B$178*EF!$S16+B$179*EF!$T16+Petroleum!$B279*Petroleum!$J$262+Petroleum!$J279)
+B$210*(EF!$V16+Petroleum!$B279*Petroleum!$D$262+Petroleum!$D279)
+B$211*(EF!$BY16+IF(Inputs!$F$239=1,MMULT(NG!$K66:$L66,Inputs!$F$117:$F$118)*NG!$M$25+NG!$M66+NG!$N66,IF(Inputs!$F$239=2,NG!$F101*NG!$G$84+NG!$G101,IF(Inputs!$F$239=4,RNG!$Y287,NG!$H101*NG!$I$84+NG!$I101)))*NG!$Z$25+NG!$Z66)
+B$217*(Electric!$B220+Electric!$C220)
)/1000000
-$B$11*((10^6/B192*B195+B$211)/Fuel_Specs!$B$70*Fuel_Specs!$E$70*Fuel_Specs!$F$70/Fuel_Specs!$B$146)
마지막에 1,000,000을 나눠줬네요? 이는 단위를 맞춰주는 기능입니다.
나눠주기 전 Process fuel을 다룬 앞의 수식들을 보면, B208~B217 항의 단위는 btu였습니다.
그 뒤에 곱해진 배출량 값들은 g/mmbtu였습니다.
따라서 이들을 직접 곱하고, 1,000,000을 나눠주어 단위를 g/mmbtu로 바꿔주는 것입니다.
그렇다면 마지막 노란색 수식만 남았습니다.
공정에 투입된 모든 Process fuel들의 Upstream과 연소 배출량을 모두 구했는데 계산식이 더 있습니다.
이는 해당 공정의 특징이라고 생각하셔도 좋을 것 같습니다. Process fuel의 Upstream과 배출계수와 관련된 계산식처럼 모든 상황에서 적용되는 수식은 아닙니다!
CCUS(Carbon Capture & Utilize & Storage)라는 공정과 관련된 것인데, 이는 배출되는 이산화탄소를 Capture하는 후처리 공정입니다. 따라서 총 배출량에서 일정 부분의 배출량을 추가적으로 빼주게 됩니다.
그 의미를 한번 이해해볼까요? 이 식만 한번 더 가져올게요
- $B$11*((10^6/B192*B195+B$211)/Fuel_Specs!$B$70*Fuel_Specs!$E$70*Fuel_Specs!$F$70/Fuel_Specs!$B$146)
맨 앞에 곱해진 B11먼저 찾아봅시다.
B11은, NG로 수소 생산 시 Capture되는 CO2의 비율을 뜻하는 값이라고합니다.
노란색 계산식 초반에, 10^6/B192*B195+B$211에서, 뒤에 더해지는 B211은 Process fuel로써 사용되는 Natural gas 에너지량이고, 앞의 1,000,000/efficiency * feedstock 투입비율의 계산의 결과는 Feedstock으로써 투입되는 Natural gas 에너지량입니다. 따라서 이 둘을 더한 10^6/B192*B195+B$211식이 뜻하는 것은 해당 공정에서 수소 1mmbtu 생산 시 투입되는 모든 Natural gas량이 됩니다.
그렇다면 그 후에 Fuel_Specs Sheet의 항들을 찾아볼까요?
B70은 Natural gas의 저위발열량 Btu/ft3이고
E70은 Natural gas의 밀도 g/ft3이고
F70은 Natural gas의 탄소 함유량 % (weight ratio)이고
B146은 이산화탄소 내 탄소 질량비입니다.
그렇다면 Natural gas의 에너지량 / 저위발열량 B70 * 밀도 E70 = 해당 Natural gas의 질량 (g)이 되고
그 Natural gas의 질량에 탄소함유량 F70을 곱하면, Natural gas 내 탄소 질량 (g)이 됩니다.
이렇게 계산한 NG의 탄소 함유량에 이산화탄소 내 탄소 질량비 B146 = 27%을 나누면, 발생가능한 이산화탄소의 질량 (g)이 되겠습니다.
전체 식은 다음과 같습니다.
(10^6/B192*B195+B$211)/Fuel_Specs!$B$70*Fuel_Specs!$E$70*Fuel_Specs!$F$70/Fuel_Specs!$B$146
= 원료와 연료로 투입된 NG로 인한 총 이산화탄소 질량
따라서 이 값에 B11, 즉 Capture되는 비율을 곱하면, CCUS장치에 의해 Capture되는 이산화탄소의 질량이 계산되므로, B236항의 전체 계산식에서 위 식을 빼주는 것입니다.
물론 B11항의 값이 0.0%로 Input되어서 실제로 Capture되는 이산화탄소의 질량은 0g이겠지만, 10%던 50%던, 사용자가 필요로 하는 값을 그 항에 입력하면 그에 따른 배출량이 계산이 될 것입니다.
이처럼 GREET에서 입력 Data를 바꾸는 등, 다양한 상황에서 사용자 맞춤형으로 배출량을 계산할 수 있는데요, 다음 포스트에서는 실무를 보시는 분들이 자주 접하실 명세서 양식 기반으로 GREET을 직접 활용하여 결과값을 도출하는 과정을 보여드리도록 하겠습니다.
감사합니다.
